8
$\begingroup$

Is it possible to interpret coefficients from a quantile regression on standardized data?

Suppose I standardize the dependent variable $y$ and the independent variable $x$ (subtract the mean and divide by the standard deviation) and then run a quantile regression for the median such as

qreg y x, q(0.5) 

in stata. The estimated coefficient for the independent variable is $0.5$. Is then the following interpretation correct:

A one standard deviation increase of the independent variable, increases the median of the dependent variable by $0.5$ standard deviation?

$\endgroup$
  • 1
    $\begingroup$ Except for a little odd wording (which I corrected in my edit) I think this is correct. $\endgroup$ – Peter Flom Sep 30 '12 at 11:53
3
$\begingroup$

Yes, that is the interpretation. One way in which you can see this is by predicting the median for different values of your standardized, each 1 unit (in this case standard deviation) appart. Than you can look at how much these predicted medians differ, and you will see that that is exactly the same number as your standardized quantile regression coefficient. Here is an example:

. sysuse auto, clear
(1978 Automobile Data)

. 
. // standardize variables
. sum price if !missing(price,weight)

    Variable |       Obs        Mean    Std. Dev.       Min        Max
-------------+--------------------------------------------------------
       price |        74    6165.257    2949.496       3291      15906

. gen double z_price = ( price - r(mean) ) / r(sd)

. 
. sum weight if !missing(price,weight)

    Variable |       Obs        Mean    Std. Dev.       Min        Max
-------------+--------------------------------------------------------
      weight |        74    3019.459    777.1936       1760       4840

. gen double z_weight = ( weight - r(mean) ) / r(sd)

. 
. // estimate the quartile regression
. qreg z_price z_weight
Iteration  1:  WLS sum of weighted deviations =  47.263794

Iteration  1: sum of abs. weighted deviations =  54.018868
Iteration  2: sum of abs. weighted deviations =  43.851751

Median regression                                    Number of obs =        74
  Raw sum of deviations 48.21332 (about -.41744651)
  Min sum of deviations 43.85175                     Pseudo R2     =    0.0905

------------------------------------------------------------------------------
     z_price |      Coef.   Std. Err.      t    P>|t|     [95% Conf. Interval]
-------------+----------------------------------------------------------------
    z_weight |   .2552875   .1368752     1.87   0.066    -.0175682    .5281432
       _cons |  -.3415908   .1359472    -2.51   0.014    -.6125966    -.070585
------------------------------------------------------------------------------

. 
. // predict the predicted median for z_weight
. // is -2, -1, 0, 1, 2
. drop _all

. set obs 5
obs was 0, now 5

. gen z_weight = _n - 3

. predict med
(option xb assumed; fitted values)

. list

     +----------------------+
     | z_weight         med |
     |----------------------|
  1. |       -2   -.8521658 |
  2. |       -1   -.5968783 |
  3. |        0   -.3415908 |
  4. |        1   -.0863033 |
  5. |        2    .1689841 |
     +----------------------+

. 
. // compute how much the predicted median
. // differs between cars 1 standard deviation
. // weight apart
. gen diff = med - med[_n - 1]
(1 missing value generated)

. list

     +---------------------------------+
     | z_weight         med       diff |
     |---------------------------------|
  1. |       -2   -.8521658          . |
  2. |       -1   -.5968783   .2552875 |
  3. |        0   -.3415908   .2552875 |
  4. |        1   -.0863033   .2552875 |
  5. |        2    .1689841   .2552875 |
     +---------------------------------+
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.