2
$\begingroup$

For random variables $X_1, \cdots, X_n$, we denote the order statistics by

\begin{align} X_{(1)} & = \min (X_1,\ldots, X_n) \\[6pt] X_{(2)} & = \text{second-smallest of } X_1,\ldots, X_n \\ & \,\,\,\vdots \\ X_{(n)} & = \max (X_1,\ldots, X_n) \end{align}

Now let $Z_1,\ldots,Z_n$ be $n$ random samples drawn from a standard Normal distribution. Let $\mu_{i:n}$ be the expected value of the $i$-th order statistic. As far as I know, there is no closed form formula for $\mu_{i:n}$, and Blom (1958)[1] provides a simple but yet fairly accurate approximation for $\mu_{i:n}$: namely

$$\mu_{i:n}=\Phi^{-1} \left(\frac{i-\frac{3}{8}}{n+\frac{1}{4}} \right),$$ where $\Phi$ is the cdf of the standard Normal.

My question is, is there any advances in the approximation for $\mu_{i:n}$ since Blom or is there any database for the values of $\mu_{i:n}$?

Any help would be appreciated, thanks.

Reference:

[1] G. Blom. Statistical Estimates and Transformed Beta Variables. 1958.

Improve this question
$\endgroup$
4
  • 2
    $\begingroup$ You should be able to generate accurate tables using numerical integration from many software packages (Mathematica, Maple, MATLAB, etc.) Is there a particular range of values of $n$ that are of interest? $\endgroup$
    – JimB
    Commented Jul 4 at 19:45
  • 1
    $\begingroup$ Apart from the extreme two order statistics ($(1)$ and $(n)$), Blom's approach works really well (though the value of $a$ in $\frac{i-a}{n+1-2a}$ needs to vary slowly with sample size, e.g. from about 0.37 at n=5, about 0.4 at n=45, to about 0.42 at n=250, and I believe it converges to 0.5 as n increases). There's still a little pattern but it's surprisingly close. For the expected values of the sample min and max there's a number of useful papers. Tippett's 1927 paper was quite good but there's been quite a few papers since. $\endgroup$
    – Glen_b
    Commented Jul 5 at 5:16
  • 2
    $\begingroup$ Rather than saying "$n$ random samples", you should write "a random sample of size $n.$" $\endgroup$
    – Michael Hardy
    Commented Jul 6 at 2:31
  • $\begingroup$ FWIW, I believe there are closed formulas, at least for some of the expectations of the order statistics, up through $n=5.$ The methods to obtain them are algebraic and recursive rather than analytic, as described in work of Balakrishnan. $\endgroup$
    – whuber ♦
    Commented Jul 6 at 15:08

1 Answer 1

Reset to default
3
$\begingroup$

Here is an example of using numerical integration to find the expected values using Mathematica which is more accurate than Blom's equation. (Note: to make a "nice" table there are formatting commands included below that aren't necessary if you just want an individual expectation.)

t = ConstantArray[".", {9, 10}];
Do[Do[t[[n - 1, i]] = ToString[NumberForm[
  NIntegrate[x  PDF[OrderDistribution[{NormalDistribution[0, 1], n}, i], x], {x, -Infinity, Infinity}],
  {6, 5}]], {i, 1, n}], {n, 2, 10}]
TableForm[t, TableHeadings -> {"n = " <> ToString[#] & /@ Range[2, 10], 
   "i = " <> ToString[#] & /@ Range[10]}]

Table of expected values

The basic command could be written as a function:

expectation[n_, i_] := 
  NIntegrate[x PDF[OrderDistribution[{NormalDistribution[0, 1], n}, i], x],
   {x, -Infinity, Infinity}]

expectation[5, 4]
(* 0.495019 *)

Exact values of the mean are available for just a few combinations of $n$ and $i$. Here are expected minimums for n = 2, 3, 4 and 5.

Mean[OrderDistribution[{NormalDistribution[0, 1], 2}, 1]]

$$-\frac{1}{\sqrt{\pi }}$$

Mean[OrderDistribution[{NormalDistribution[0, 1], 3}, 1]]

$$-\frac{3}{2 \sqrt{\pi }}$$

Mean[OrderDistribution[{NormalDistribution[0, 1], 4}, 1]]

$$-\frac{6 \tan ^{-1}\left(\sqrt{2}\right)}{\pi ^{3/2}}$$

Mean[OrderDistribution[{NormalDistribution[0, 1], 5}, 1]]

$$\frac{5}{2 \sqrt{\pi }}-\frac{15 \tan ^{-1}\left(\sqrt{2}\right)}{\pi ^{3/2}}$$

Improve this answer
$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.