4
$\begingroup$

I have a data set with 561 observations. I want to compare two groups on an outcome measure with 3 categories. I have a couple of covariates.

I used the following syntax (Stata SE 12.1):

mlogit outcome_measure covariate_1 covariate_2 i.covariate_3 i.covariate_4 group

To check for Independence from Irrelevant Attributes (IIA) I used

mlogtest , haus

This gave me the following output: output of "mlogtest , haus"

I understand that this means that the data do not meet the IIA assumption.

Stata then suggests to use the suest (Seemingly Unrelated Estimation) command. I could try this, but I am not sure if this is a valid alternative. What do you guys think?

EDIT (2013-09-18):

@GUNG: I asked one of my statistics professors. He said that the additional tests won't be performed if the assumption is not violated for one of the outcomes (in the case of three outcome categories). He therefore thinks that I can proceed with the mlogit model.

@Dimitriy V Masterov I ran the Small-Hsiao IIA test. These are the outcomes: Outcomes Stata Small-Hsiao IIA test

I guess this means IIA is not violated. Do you agree?

EDIT (2013-09-22):

As Dimitriy V. Masterov suggested, I ran the new syntax for Hausman. Because I have 3 categories in my outcome variable, I compared the Full model to all models with one category of my outcome variable omitted (Full vs. 1+2, Full vs. 1+3, Full vs. 2+3). These are the outcomes:

Hausman - Ignoring Category 1 Hausman - Ignoring Category 2 Hausman - Ignoring Category 3

It looks like leaving out the third category changes the model significantly. Does this mean that I cannot use Multinomial Logistic Regression and that I should move to (the suggested) suest (Seemingly Unrelated Estimation)?

suest is giving the following outputs:

suest output

The output looks fine to me and it supports my hypothesis, but I am not sure if suest is valid, what it assumptions are and how I can test these.

Any comments are welcome!

$\endgroup$
2
  • 2
    $\begingroup$ I don't know Stata, but it seems that the test of Categ_1 is non-significant, and the other two, having negative values for the chi2, must not "meet asymptotic assumptions". Thus, I'm not sure that you can validly conclude that "the data do not meet the IIA assumption". Possibly nothing can be concluded relative to the IIA assumption. Instead, I think you want to find out what the asymptotic assumptions of the Hausman test are, and what it is about your data that violate them. $\endgroup$ Sep 16, 2013 at 2:25
  • 2
    $\begingroup$ On page 245 of Long & Freese (2006) they write that negative test statistics are common. They also cite Hausman & McFadden (1984, p.1226) who say a negative value means IIA was not violated. The absence of p-values is puzzling. What does Small-Hsiao IIA test produce? $\endgroup$
    – dimitriy
    Sep 18, 2013 at 7:03

2 Answers 2

4
$\begingroup$

Depending on your version of Stata, you can try the new syntax for hausman:

webuse sysdsn1
mlogit insure age male 
estimates store Full
mlogit insure age male if insure !="Uninsure":insure
estimates store Restricted
hausman Restricted Full, alleqs constant

I can't get mlogtest to work with Stata 13 (it's an older, user-written command), so I can't verify it's the same error, but here's an example of a Hausman test that fails:

mlogit insure age male if insure !="Prepaid":insure
hausman Restricted Full, alleqs constant

The test involved calculating the test statistic $H = (b-B)'V(b-B)^{-1}(b-B)$. The problem has to do with the estimator of the variance $V(b-B)$ as $V(b)-V(B)$, which is only asymptotically feasible. $b$ and $B$ are the restricted and unrestricted coefficient vectors. Here it isn't a proper variance matrix, and the Hausman test becomes undefined.

suest estimates the simultaneous variance-covariance of the coefficients, and you can use it in the following way:

suest Restricted Full, noomitted
test [Restricted_Uninsure = Full_Uninsure], cons

suest estimates $V(b-B)$ by $V(b)-Cov(b,B)-Cov(B,b)+V(B)$. This is always admissible, so the resulting test is always well defined. I would prefer this.

You will have to loop over dropped categories to get all the tests.


@marquisdecarabas Something like this:

webuse sysdsn1
mlogit insure age male 
estimates store m1, title("Full Model")
mlogit insure age male if insure != "Uninsure":insure
estimates store m2, title("Not Uninsured")
mlogit insure age male if insure != "Prepaid":insure
estimates store m3, title("Not Prepaid")

suest m1 m2 m3, noomitted
test [m1_Prepaid = m2_Prepaid], cons
test [m1_Uninsure = m3_Uninsure], cons accum
$\endgroup$
5
  • $\begingroup$ If one of the comparisons (e.g. Full vs. 1+2) using -suest- was significant, while the remaining two were not, does this mean the IIA assumption was violated and other estimation strategies (mprobit, mixed mlogit, nlogit) should be used instead? $\endgroup$ Nov 18, 2015 at 23:11
  • 1
    $\begingroup$ @marquisdecarabas I believe you want to do a joint test using the accumulate option in test. See the addendum above. $\endgroup$
    – dimitriy
    Nov 18, 2015 at 23:46
  • $\begingroup$ Thanks, I saw that in the -suest- help and ran the test w/ the acc option. If I have 4 categories of the outcome, would I run test test [FULL_outA=restrict1_outA],cons test [FULL_outB=restrict1_outB],cons acc test [FULL_outC=restrict2_outC],cons acc test [FULL_outB=restrict2_outB],cons acc test [FULL_outC=restrict3_outC],cons acc test [FULL_outA=restrict3_outA],cons acc right? $\endgroup$ Nov 19, 2015 at 1:06
  • 1
    $\begingroup$ That seems right. $\endgroup$
    – dimitriy
    Nov 19, 2015 at 1:12
  • $\begingroup$ Very helpful as always, @DimitriyVMasterov. I will give you a tip of the hat in my acknowledgements section. $\endgroup$ Nov 19, 2015 at 1:21
1
$\begingroup$

Personally, I think that if you are worried about IIA you should just use a multinomial probit, with a fully general error covariance matrix. (See Train's Discrete Choice Methods with Simulation Chapter 5) Computers are generally fast enough to do that these days.

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.